#! /bin/csh -f
# $Header: sbust,v 1.1 95/01/06 12:18:02 k2mm Exp $

set nonomatch
rm -f zbust-*

cat rqth \
    | grep 'qth:' \
    | grep -v '=1	--=0' \
    | sed -e 's/qth: *//' -e 's/	.*//' \
    | cat - rcalls \
    | sort -u \
    > zbust-ref

cat rqth \
    | grep '=1	--=0' \
    | sed -e 's/qth: //' -e 's/	.*//' \
    | sort -u \
    > zbust-un

set ased = (				\
    "s=^.\(.*\)=.\1="			\
    "s=^\(.\).\(.*\)=\1.\2="		\
    "s=^\(..\).\(.*\)=\1.\2="		\
    "s=^\(...\).\(.*\)=\1.\2="		\
    "s=^\(....\).\(.*\)=\1.\2="		\
    "s=^\(.....\).\(.*\)=\1.\2="	\
)

echo --NG--
foreach x ( `cat zbust-un` )
    set nChPlusOne = ` echo $x | wc -c `
    set i = 1
    while ( $i < $nChPlusOne )
	set regex = ` echo $x | sed -e $ased[$i]:q `
	set ngot = ` grep $regex:q zbust-ref | wc -l `
	if ( $ngot >= 1 ) then
	    set agot = ` grep $regex:q zbust-ref `
	    echo "${x}: $agot" | tee -a zbust-ng
	endif
	@ i++
    end
end

echo --OK--
cat zbust-ng | sed 's/:.*//' | sort - zbust-un | uniq -u > zbust-ok
fgrep -f zbust-ok lfmt